第 5 回アセンブリ言語

本日の内容

5-1. アセンブリ言語
5-2. 演算子
5-3. 関数
5-4. アセンブル
5-5. シミュレータを使ったデバッグ
5-6. 実行
5-7. 演習問題

このドキュメントは http://edu.net.c.dendai.ac.jp/ 上で公開されています。

5-1. アセンブリ言語

基本書式

アセンブリ言語はテキストファイルに記述します。アセンブラのユーザーズマニュアル AVR Assembler Assembler source に示されているように記述します。「ラベル: ニモニックオペランド」を空白で区切って記述します。ラベルの前に空白があってはいけません。また、セミコロン(;)の後ろはコメントとしてアセンブル時に無視されます。ニモニックの位置には他にディレクティヴ、マクロなどを置くことができます。


ラベル  ニモニック オペランド コメント
.org    0x0013
reset:
        ldi        r16,low(RAMEND)
        out        SPL,r16

演算

アセンブリ言語中で定数の演算式を書くことが出来ます。アセンブラのユーザーズガイドの AVR Assembler Expressions にあるように C 言語で許されているような演算子がそのまま使えます。但し、レジスタの内容は演算の対象ではありません。

ディレクティヴ

アセンブラとはニモニックとオペランドから機械語を生成するものですが、利便性を向上するためのアセンブラの機能があります。ディレクティヴとはアセンブラに対する指示をする命令です。ディレクティヴはピリオド(.)で始めます。

良く使うディレクティヴを紹介します。

cseg, dseg, eseg: それぞれ、 Code, Data, EEPROM の内容を定義するという意味です。
equ: 任意の値を持つラベルを定義します。再定義できません。計算値も定義できます。
def: レジスタにラベルを定義します。再定義できません。これを使用すると、レジスタの利用を論理的に表示できるので、必ず使うことを推奨します。
org: 実際のプログラムやデータを置く始点となる番地を指定します。
db, dw, dd, dq: データをじかに書きます。 db は Byte, dw は Word(16bit)の定義に使います。カンマ(,)で区切るといくつも定義できます。なお、プログラム領域(cseg で定義される領域)は 16bit です。 lpm 命令で 8bit ずつ取り出す場合、下位 8bit がアドレスの偶数番地、上位 8bit が奇数番地に対応します。さらに、奇数個のデータを入れると、上位 8bit が $00 で埋められます。
byte: dseg で SRAM の領域にラベル付きの領域を定義する際に使用します。
exit: アセンブリのリストの最後を示します。
macro, endmacro: マクロを定義します。 macro のオペランドにマクロ名を指定します。マクロ定義の中で引数として @0 から @9 の 10 個の仮引数が使えます。なお、AVR のアセンブラのマクロ中のラベルはローカルにしか使用できませんので、マクロ中に定義したラベルに外部からアクセスすることはできません。なお、グローバルなラベルを使用するには #define 疑似命令を使用する手がありますが、こちらこちらで基本的に一行で記述しなければならず、複数行を書くには(\)を使用した継続行を使用する必要があります。

5-2. 演算子

アセンブリ言語で式を書くことができます。値はリテラルを使用でき、レジスタやメモリの内容を使うことはできません

なお、これらは一部なので、詳しくはアセンブラマニュアルの Operator を参照してください。

!: 論理否定: 0以外なら0を、0は1を返します
&&: 論理積
||: 論理和
~: ビット反転
&: ビット積
|: ビット和

5-3. 関数

EQU などで使用できる関数を下記に示します。なお、これらは一部なので、詳しくはアセンブラマニュアル Expressions を参照してください。

LOW(式): 式の値の下位8bitを取り出します
HIGH(式): 式の値の上位8bitを取り出します
EXP2(式): 式の値の２のべき乗を返します。 (1<<式)と同等です
LOG2(式): 式の値の 2 を底とした対数の整数部分を返します
INT(式): 式の値を切り捨てます
FRAC(式): 式の値の小数部分を取り出します
ABS(式): 式の値の絶対値を返します

5-4. アセンブル

さて、この節では実際にプログラムを作成する手順を説明します。

Atmel Studio を起動します。
「ファイル→新規作成→プロジェクト」を選びます。
「インストール済み」で Assembler を選び、名前にプロジェクト名を入れます
Device Family で ATmega を選び、を選びます
main.asm という編集画面が開きますので、プログラムを入力します。
「ファイル→ main.asm の保存」でプログラムを保存します。
「ビルド→ソリューションのビルド」でアセンブルします。
アセンブルエラーが出た場合、エラーをダブルクリックするとエラーの出た行へカーソルが移動します。

5-5. シミュレータを使ったデバッグ

アセンブルしたプログラムはシミュレータで動作を観察できます。「プロジェクト→ プロジェクト名のプロパティ」を選ぶと設定画面が出ます。 Tool の設定画面で、 Simulator を選ぶとソフトウェアシミュレータを使えるようになります。シミュレータはプログラムを一命令ずつ動かしたり、指定した所まで動かして止めたり出来ます。

シミュレータはテープレコーダのボタンのようなボタンで操作をします。なお、右側の画面でマイコンの状態を見ることができます。

プログラムリストの行をダブルクリックすると左側に赤い丸が付きます。これをブレークポイントと言います。矢印一つの Run ボタンを押すと、ブレークポイントで停止します。これにより、プログラムの途中のレジスタの値などをチェックできます。

その他、一命令だけ実行する Step Into, Call 命令に関しては戻って来るまで一括で実行する Step over, サブルーチン中から抜け出すまで実行する Step out があります。

なお、実行中にI/Oのボタンを押すと、その値に変化させることができます。

5-6. 実行

プログラムの書き込み

Arduino をコンピュータに接続します
デバイスマネージャーで、Arduino のデバイス識別子を調べます。
Windows Power Shell, cmd.exe, Terminal など、コマンドの入力できる画面で、cdコマンドなどでプログラムを作成したフォルダに行き、さらに、 Debug というフォルダに入ります。 dirコマンドなどで「プロジェクト名.hex」というファイルがあることを確認します。
下記のprogram328.batプログラムをフォルダに置きます。
.\program328.bat COM3 flashuno.hex とするとプログラムがArduino に書き込めます。

program328.bat(Windows 用)

以下のプログラムを program.bat というテキストファイルに収めます。


set root=C:\Users\sakamoto\Downloads\avrdude-v8.1-windows-x64
set dude=%root%\avrdude.exe
set conf=%root%\avrdude.conf
%dude%  -C %conf% -p m328p -c arduino -P %1  -D -U flash:w:"%2":i

なお、上記にsakamotoという名前が入っています。これを自分のパソコンのアカウント名などに置き換える必要があります。

Arduino をコンピュータに接続します
デバイスマネージャーで、Arduino のデバイス識別子を調べます。 Arduino Leonardo は特殊で、通常はUSBはシリアル回線として接続していて、リセットがかかるとブートローダー用に別のシリアルポートが開かれます。そこで、リセットをかけたときに出るデバイスの識別子(COM?)を調べます。
Windows Power Shell, cmd.exe, Terminal など、コマンドの入力できる画面で、cdコマンドなどでプログラムを作成したフォルダに行き、さらに、 Debug というフォルダに入ります。 dirコマンドなどで「プロジェクト名.hex」というファイルがあることを確認します。
下記のprogram32u4.batプログラムをフォルダに置きます。
リセットしたときに出るデバイス識別子で .\program32u4.bat COM? flashuno.hex とタイプし、Arduino Leonardo の基板上にあるリセットボタンを押してから上記のコマンドをReturnで起動するとプログラムがArduino に書き込めます。

program32u4.bat(Windows 用)

以下のプログラムを program32u4.bat というテキストファイルに収めます。


set root=C:\Users\sakamoto\Downloads\avrdude-v8.1-windows-x64
set dude=%root%\avrdude.exe
set conf=%root%\avrdude.conf
%dude%  -C %conf% -p m32u4 -c avr109 -P %1  -D -U flash:w:"%2":i

なお、上記にsakamotoという名前が入っています。これを自分のパソコンのアカウント名などに置き換える必要があります。

Arduino をコンピュータに接続します
デバイスマネージャーで、Arduino のデバイス識別子を調べます。
Windows Power Shell, cmd.exe, Terminal など、コマンドの入力できる画面で、cdコマンドなどでプログラムを作成したフォルダに行き、さらに、 Debug というフォルダに入ります。 dirコマンドなどで「プロジェクト名.hex」というファイルがあることを確認します。
下記のprogram4809.ps1プログラムをフォルダに置きます。
Set-ExecutionPolicy RemoteSigned -Scope CurrentUserを打って、Power Shell のスクリプトを実行できるようにします。
.\program4809.ps1 COM3 flashuno.hex とするとプログラムがArduino に書き込めます。

program4809.ps1(Windows 用)

以下のプログラムを program4809.ps1 というテキストファイルに収めます。


param(
    [string]$COMPORT,
    [string]$HEXFILE
)
$root="C:\Users\sakamoto\Downloads\avrdude-v8.1-windows-x64"
$dude = Join-Path $root "avrdude.exe"
$conf = Join-Path $root "avrdude.conf"
$port = new-Object System.IO.Ports.SerialPort $COMPORT,1200,'None',8,'One'
$port.DtrEnable = $true
$port.Open()
Start-Sleep -Milliseconds 100
$port.DtrEnable = $false
$port.Close()
Start-Sleep -Seconds 2
& $dude  -C $conf -patmega4809 -cjtag2updi -v -V -P $COMPORT -e -D -U flash:w:"$HEXFILE":i

なお、上記にsakamotoという名前が入っています。これを自分のパソコンのアカウント名などに置き換える必要があります。

5-7. 演習問題

演習5-1

サンプルプログラムflashuno.asm の各ディレクティヴがどのような意味か、全て調べなさい。

演習5-2

サンプルプログラムflashuno.asm を機能毎に区分し、各機能を説明しなさい。

演習5-3

サンプルプログラムswitchtraining.asm を動作させなさい。

また、プログラムを読み、どのような動きをするのか、説明しなさい。

演習5-4

サンプルプログラムswitchtraining.asm の各ディレクティヴがどのような意味か、全て調べなさい。

演習5-5

サンプルプログラムswitchtraining.asm を機能毎に区分し、各機能を説明しなさい。

switchtraining.asm


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,high(RAMEND)
        out     SPH,r16 
        ldi     r16,low(RAMEND)
        out     SPL,r16
        sbi     ddrb,pb5
        cbi     ddrd,pd4
        sbi     portd,pd4
main:
        sbi     portb,pb5
        sbis    pind,pd4
        rjmp    onl
        rcall   shortwait
        rjmp    off
onl:
        rcall   longwait
off:
        cbi     portb,pb5
        sbic    pind,pd4
        rjmp    offl
        rcall   shortwait
        rjmp    main
offl:
        rcall   longwait
        rjmp    main
  
.equ    shorttime = 4
.equ    longtime = 40
.def    wreg0 = r20
.def    wreg1 = r21
.def    wreg2 = r22
shortwait:
        ldi     wreg0,shorttime
        rjmp    wait0
longwait:
        ldi     wreg0,longtime
wait0:
        ldi     wreg1,0
wait1:
        ldi     wreg2,0
wait2:
        nop
        dec     wreg2
        brne    wait2
        dec     wreg1
        brne    wait1
        dec     wreg0
        brne    wait0
        ret
.exit


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,high(RAMEND)
        out     SPH,r16 
        ldi     r16,low(RAMEND)
        out     SPL,r16
        sbi     ddrc,pc7
        cbi     ddrd,pd4
        sbi     portd,pd4
main:
        sbi     portc,pc7
        sbis    pind,pd4
        rjmp    onl
        rcall   shortwait
        rjmp    off
onl:
        rcall   longwait
off:
        cbi     portc,pc7
        sbic    pind,pd4
        rjmp    offl
        rcall   shortwait
        rjmp    main
offl:
        rcall   longwait
        rjmp    main
  
.equ    shorttime = 4
.equ    longtime = 40
.def    wreg0 = r20
.def    wreg1 = r21
.def    wreg2 = r22
shortwait:
        ldi     wreg0,shorttime
        rjmp    wait0
longwait:
        ldi     wreg0,longtime
wait0:
        ldi     wreg1,0
wait1:
        ldi     wreg2,0
wait2:
        nop
        dec     wreg2
        brne    wait2
        dec     wreg1
        brne    wait1
        dec     wreg0
        brne    wait0
        ret
.exit


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,low(RAMEND)
        out     CPU_SPL,r16
        ldi     r16,high(RAMEND)
        out     CPU_SPH,r16 
        ; PE2
        lds     r16,PORTE_DIR
        ori     r16,1<<2 
        sts     PORTE_DIR,r16
        ; PC6
        lds     r16,PORTC_PIN6CTRL
        ori     r16,PORT_PULLUPEN_bm
        sts     PORTC_PIN6CTRL,r16

main:
        lds     r17,PORTE_OUT
        ori     r17,1<<2
        sts     PORTE_OUT,r17
        lds     r17,PORTC_IN
        sbrs    r17,6
        rjmp    onl
        rcall   shortwait
        rjmp    off
onl:
        rcall   longwait
off:
        lds     r17,PORTE_OUT
        andi    r17,~(1<<2)
        sts     PORTE_OUT,r17
        lds     r17,PORTC_IN
        sbrc    r17,6
        rjmp    offl
        rcall   shortwait
        rjmp    main
offl:
        rcall   longwait
        rjmp    main
  
.equ    shorttime = 1
.equ    longtime = 10
.def    wreg0 = r20
.def    wreg1 = r21
.def    wreg2 = r22
shortwait:
        ldi     wreg0,shorttime
        rjmp    wait0
longwait:
        ldi     wreg0,longtime
wait0:
        ldi     wreg1,0
wait1:
        ldi     wreg2,0
wait2:
        nop
        dec     wreg2
        brne    wait2
        dec     wreg1
        brne    wait1
        dec     wreg0
        brne    wait0
        ret
.exit

演習5-6

次の操作をする命令の組を書きなさい

レジスタ r16 に 0xA0 を入れる
出力ポート PORTB5を HIGHにする
r16 の値が 0x32 かどうか調べ、等しければ label0 に飛び、等しくなければ label1 に飛ぶ
r16 の値が 0x45 と比較し、大きければ label0 に飛び、それ以下なら label1 に飛ぶ
rcall sub0 を 100回呼ぶ

演習5-7

flashuno.asm のプログラムを改造して、点滅の速さが2倍になるようにしよう

演習5-8

flashuno.asm のプログラムを改造して、点滅の速さが1/2倍になるようにしよう

演習5-9

r16に入れた数だけ、0.1秒ずつLEDを点滅した後、1秒消灯する nblink というサブルーチンを作りなさい。さらに、次のプログラムと結合して正常に動作することを確かめなさい。


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,high(RAMEND)
        out     SPH,r16 
        ldi     r16,low(RAMEND)
        out     SPL,r16
    
        sbi     ddrb,pb5
main:
        ldi     r16,0
loop:
        inc     r16
        push    r16
        rcall   nblink
        pop     r16
        cpi     r16,4
        brne    loop
        rjmp    main


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,high(RAMEND)
        out     SPH,r16 
        ldi     r16,low(RAMEND)
        out     SPL,r16
        sbi     ddrc,pc7
main:
        ldi     r16,0
loop:
        inc     r16
        push    r16
        rcall   nblink
        pop     r16
        cpi     r16,4
        brne    loop
        rjmp    main


.cseg
.org    0x0000
        rjmp        reset
.org    INT_VECTORS_SIZE
reset:
        ldi     r16,low(RAMEND)
        out     CPU_SPL,r16
        ldi     r16,high(RAMEND)
        out     CPU_SPH,r16 
        ; PE2
        lds     r16,PORTE_DIR
        ori     r16,1<<2 
        sts     PORTE_DIR,r16
main:
        ldi     r16,0
loop:
        inc     r16
        push    r16
        rcall   nblink
        pop     r16
        cpi     r16,4
        brne    loop
        rjmp    main

演習5-10

番兵が0の数列をdbで確保し、各数列の値でblink()メソッドを呼ぶプログラムを書きなさい。


sample:
.db     3,3,7,0
.equ    sampleadr = sample<<1

演習5-11

4番とGNDをつないだときだけ、LED が点灯するプログラムを作りなさい。

演習5-12

4番とGNDをつないだときは、1秒おきに2回LEDが点滅、つないでない時は 1秒おきに短くLEDが点滅するプログラムを作りなさい。

演習5-13

4番とGNDをつないだときは、1秒おきにLEDが1回点滅、2回点滅、3回点滅、 1回点滅,2回点滅、3回点滅と繰り返すが、つないでない時は同じ回数の点滅を繰り返すプログラムを作りなさい。つまり、3回点滅の時に線を外せば、そのまま3回点滅を繰り返し、 1回点滅の時に線を外すと1回点滅を繰り返すようにしなさい。

坂本直志 <sakamoto@c.dendai.ac.jp>
東京電機大学工学部情報通信工学科

第 5 回 アセンブリ言語

本日の内容

5-1. アセンブリ言語

基本書式

演算

ディレクティヴ

5-2. 演算子

5-3. 関数

5-4. アセンブル

5-5. シミュレータを使ったデバッグ

5-6. 実行

プログラムの書き込み

program328.bat(Windows 用)

program32u4.bat(Windows 用)

program4809.ps1(Windows 用)

5-7. 演習問題

演習5-1

演習5-2

演習5-3

演習5-4

演習5-5

switchtraining.asm

演習5-6

演習5-7

演習5-8

演習5-9

演習5-10

演習5-11

演習5-12

演習5-13

第 5 回アセンブリ言語